//gradle脚本执行所需要
buildscript {
    ext {
        springBootVersion = '1.5.14.RELEASE'
        springCloudVersion = 'Edgware.SR4'
    }

    repositories {
        maven {
            url "http://maven.aliyun.com/nexus/content/groups/public/"
        }
        mavenCentral()
        jcenter()
    }
    dependencies {
        //引入spring-boot插件
        classpath "org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}"
        //引入dependency-management插件
        classpath "io.spring.gradle:dependency-management-plugin:1.0.3.RELEASE"
    }
}


allprojects {

    apply plugin: "idea"

    group = 'com.feitian.starter'
    version = '1.0.0-SNAPSHOT'

    repositories {
        mavenLocal()
        maven {
            url "http://maven.aliyun.com/nexus/content/groups/public/"
        }
        mavenCentral()
        jcenter()
    }
}


subprojects {
    apply plugin: "java"
    apply plugin: "groovy"
    apply plugin: "io.spring.dependency-management"

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    dependencyManagement {
        imports {
            mavenBom("org.springframework.boot:spring-boot-dependencies:${springBootVersion}")
        }
    }

    compileGroovy {
        groovyOptions.forkOptions.jvmArgs = ['-noverify']
    }

    sourceSets {
        main {
            groovy { srcDirs = ["src/main/groovy", "src/main/java"] }
            java { srcDirs = [] }
        }
        test {
            groovy { srcDirs = ["src/test/groovy", "src/test/java"] }
            java { srcDirs = [] }
        }
    }

    dependencies {
        compile 'org.codehaus.groovy:groovy-all:2.4.3'
    }
}

//core
project(":entry") {

    dependencies {
        compile 'com.fasterxml.jackson.core:jackson-databind'
        compile "io.springfox:springfox-swagger-ui:2.7.0"
        compile 'io.springfox:springfox-swagger2:2.9.2'
        compile "commons-beanutils:commons-beanutils:1.9.3"
        //2.0
        //compile group: 'org.hibernate', name: 'hibernate-validator', version: '6.0.16.Final'
        compile 'org.hibernate:hibernate-validator'
        compile 'log4j:log4j:1.2.14'
        compile 'com.github.pagehelper:pagehelper-spring-boot-starter:1.2.5'
        compile group: 'org.javatuples', name: 'javatuples', version: '1.2'
        compileOnly 'org.projectlombok:lombok:1.16.18'
        compile('com.google.guava:guava:21.0') {
            force = true
            transitive = false
        }
        /** joda-time */
        compile group: 'joda-time', name: 'joda-time', version: '2.10'
    }

    apply plugin: "maven"

    uploadArchives {
        repositories {
            mavenDeployer {
                pom.groupId = "com.feitian.starter"
                pom.version = "1.0.0-SNAPSHOT"
                pom.artifactId = "feitian-entry-starter"

                repository(url: "http://192.168.36.100:8081/artifactory/gradle-dev-local/") {
                    authentication(userName: "jenkins-admin", password: "feitian1234567890")
                }
                repository(url: "file://${System.getProperty("user.home")}/.m2/repository")
            }
        }
    }
}

//core
project(":core") {

    dependencies {
        compile project(":entry")
        compileOnly 'org.projectlombok:lombok:1.16.18'
        compile 'org.springframework.boot:spring-boot-starter'
        compile "org.springframework.boot:spring-boot-starter-actuator"
        compile "org.springframework.boot:spring-boot-starter-logging"
        compile 'org.springframework.boot:spring-boot-starter-web'
        compile 'org.springframework.boot:spring-boot-starter-jdbc'
        compile 'org.springframework.boot:spring-boot-starter-aop'
        compile 'net.sf.ehcache:ehcache-core:2.6.11'

        /** shiro */
        compile('org.apache.shiro:shiro-all:1.3.2'){
            exclude module: 'shiro-core'
        }
        compile('org.apache.shiro:shiro-ehcache:1.3.2') {
            exclude module: 'shiro-core'
        }


    }

    apply plugin: "maven"

    uploadArchives {
        repositories {
            mavenDeployer {
                pom.groupId = "com.feitian.starter"
                pom.version = "1.0.0-SNAPSHOT"
                pom.artifactId = "feitian-spring-boot-starter"

                repository(url: "http://192.168.36.100:8081/artifactory/gradle-dev-local/") {
                    authentication(userName: "jenkins-admin", password: "feitian1234567890")
                }
                repository(url: "file://${System.getProperty("user.home")}/.m2/repository")
            }
        }
    }
}

//service
project(":cloud") {

    apply plugin: "io.spring.dependency-management"

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
        }
    }

    dependencies {
        compile project(":core")
        compileOnly 'org.projectlombok:lombok:1.16.18'
        //2.0
        //compile 'org.springframework.cloud:spring-cloud-starter-netflix-eureka-client'
        //compile 'org.springframework.cloud:spring-cloud-starter-netflix-eureka-server'
        //compile 'org.springframework.cloud:spring-cloud-starter-openfeign'
        //compile "org.springframework.cloud:spring-cloud-starter-netflix-hystrix"
        
        compile "org.springframework.cloud:spring-cloud-starter-eureka"
        compile "org.springframework.cloud:spring-cloud-starter-feign"
        compile "org.springframework.cloud:spring-cloud-starter-hystrix"
    }

    apply plugin: "maven"

    uploadArchives {
        repositories {
            mavenDeployer {
                pom.groupId = "com.feitian.starter"
                pom.version = "1.0.0-SNAPSHOT"
                pom.artifactId = "feitian-spring-cloud-starter"

                repository(url: "http://192.168.36.100:8081/artifactory/gradle-dev-local/") {
                    authentication(userName: "jenkins-admin", password: "feitian1234567890")
                }
                repository(url: "file://${System.getProperty("user.home")}/.m2/repository")
            }
        }
    }
}

//service
project(":sample") {

    dependencies {
        compile project(":core")
        compileOnly 'org.projectlombok:lombok:1.16.18'
        compile group: 'mysql', name: 'mysql-connector-java', version: '5.1.27'
        compile group: 'com.alibaba', name: 'druid', version: '1.0.29'
        compile 'org.springframework.boot:spring-boot-starter-test'
        compile "org.springframework.boot:spring-boot-devtools"
    }
}