# Stata论文复现：数字金融与融资约束对财务绩效的影响——来自中国新能源企业的企业层面证据


 

>  **作者**：乔刚 (南京大学)  <br>  **邮箱**：<qiaogang1995@126.com> 

**编者按**：本文主要摘译自下文，特此致谢！ <br>
Source：Wu, Y., S. Huang, 2022, The effects of digital finance and financial constraint on financial performance: 
Firm-level evidence from china's new energy enterprises, Energy Economics, 112: 106158. [-Link-](https://www.sciencedirect.com/science/article/pii/S0140988322003127?fr=RR-2&ref=pdf_download&rr=80233c67d9f30e6e),-PDF-, Replication 

[toc]

## 1. 文章背景介绍

中国过去四十年的经济增长速度是惊人的，但伴随着显著的要素投入和能源消耗水平，这可能导致环境退化和能源危机。因此，新能源产业的发展为解决上述问题提供了机遇。在影响新能源行业驱动因素中，金融资源的可用性和相关问题最受关注，同时数字金融的出现为解决新能源行业的融资需求提供了新的契机。

研究问题：本研究探讨了数字金融如何促进新能源产业的发展。具体而言，使用企业层面的数据，从企业融资约束和财务绩效的角度评估数字金融对新能源的影响。

研究数据：本研究调查了沪深新能源上市公司的面板数据集。这些公司的一般信息来源于中国能源网，其财务数据来自 Wind 和 CSMAR 数据库。
与数字金融相关的数据来自北京大学数字金融研究所。最终样本包含 157 家新能源上市公司和 926 份 2011 年至 2018 年的观察结果。

研究方法：结合静态和动态面板模型进行估计。具体使用静态固定效应模型和动态广义矩估计方法。

研究结论：
（1）融资约束与新能源公司的财务业绩之间存在着强有力的负相关关系。
（2）数字金融技术的发展可以对新能源公司的财务业绩产生积极影响。但是，在存在资金约束的情况下，数字金融的作用将会减弱。
（3）数字金融和金融约束可能会对财务绩效产生不同的影响，这取决于公司的规模和所有权类型。具体而言，数字金融的促进作用在小企业和非国有企业中较高，金融约束的负面作用在大企业中较高。


## 2. 实证结果

### 2.1 模型设定

本文考虑了经济活动的一致性以及财务绩效和融资约束之间潜在的反向因果关系。具体而言，本研究采用了以下动态面板模型：

$$y_{it}=\alpha\:y_{it-1}+\mathbf{X_{it}}'\beta+\mathbf{Z_{it}}'\sigma+\mathbf{u_i}+\mathbf{\lambda_t}+\varepsilon_{it}  \quad{(1)} $$ 

其中，$y_{it}$ 为企业财务绩效（ROA / ROE），$y_{it-1}$ 为财务绩效滞后一期，$X_{it}$ 为数字金融（DFIndexCity）和融资约束（KZIndex / FCIndex），$Z_{it}$ 为企业和地区层面系列控制变量，$\mathbf{u_i}$ 为固定效应，$\mathbf{\lambda_t}$ 为时间固定效应，$\varepsilon_{it}$ 表示误差项。

### 2.2 基准结果
在进行系统广义矩估计（SGMM）估计之前，将静态模型作为基准进行估计。结果表明，在固定年份、省份和行业影响的前提下，无论是否包括控制变量，
数字金融对财务绩效都有正向影响，而融资约束对财务绩效则有负向影响。交互项不显著，表明融资约束在静态模型中不起调节作用。

```
*Static model 


reghdfe ROA dfindexcity KZIndex, absorb(year industry province) vce(cluster province)
est store k1

reghdfe ROA dfindexcity KZIndex Size Age SOE Topshare Boardsize CEOduality Findev, absorb(year industry province) vce(cluster province)
est store k2

reghdfe ROA dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev, absorb(year industry province) vce(cluster province)
est store k3

reghdfe ROE dfindexcity KZIndex, absorb(year industry province) vce(cluster province)
est store k4

reghdfe ROE dfindexcity KZIndex Size Age SOE Topshare Boardsize CEOduality Findev, absorb(year industry province) vce(cluster province)
est store k5

reghdfe ROE dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev, absorb(year industry province) vce(cluster province)
est store k6

esttab k1 k2 k3 k4 k5 k6 , order(dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev) compress nogap ///
star(* 0.10 ** 0.05 *** 0.01) mtitles("ROA" "ROA" "ROA" "ROE" "ROE" "ROE") se b(%9.3f) se(%9.3f) noconstant
```
\
 ![\:](https://fig-lianxh.oss-cn-shenzhen.aliyuncs.com/%E4%BD%9C%E8%80%85%E4%B9%94%E5%88%9A_%E6%95%B0%E5%AD%97%E9%87%91%E8%9E%8D%E4%B8%8E%E8%9E%8D%E8%B5%84%E7%BA%A6%E6%9D%9F%E5%AF%B9%E8%B4%A2%E5%8A%A1%E7%BB%A9%E6%95%88_Fig1.png) 

```
*Dynamic model
ssc install xtabond2,replace
xtabond2 ROA L.ROA dfindexcity KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 4)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store dy1

xtabond2 ROA L.ROA dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(df_KZ, lag(2 4)) gmm(Size, lag(2 4)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store dy2

xtabond2 ROE L.ROE dfindexcity KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 4)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store dy3

xtabond2 ROE L.ROE dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 4)) ///
gmm(KZIndex, lag(2 5)) gmm(df_KZ, lag(2 4)) gmm(Size, lag(2 5)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store dy4

esttab dy1 dy2 dy3 dy4, order(L.ROA L.ROE dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev) compress nogap ///
star(* 0.10 ** 0.05 *** 0.01) mtitles("ROA" "ROA" "ROE" "ROE" "ROS" "ROS") se b(%9.3f) se(%9.3f) noconstant

*Dynamic model with RD controlled
xtabond2 ROA L.ROA dfindexcity KZIndex Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7, gmm(ROA, lag(2 2)) ///
gmm(KZIndex, lag(2 3)) gmm(RD_intensity, lag(2 5)) gmm(Size, lag(2 5)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store rdyr1

xtabond2 ROA L.ROA dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7, gmm(ROA, lag(2 2)) ///
gmm(KZIndex, lag(2 4)) gmm(df_KZ, lag(2 3)) gmm(RD_intensity, lag(2 6)) gmm(Size, lag(2 6)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store rdyr2

xtabond2 ROE L.ROE dfindexcity KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7 RD_intensity, gmm(ROE, lag(2 3)) gmm(KZIndex, lag(2 4)) ///
gmm(RD_intensity, lag(2 4)) gmm(Size, lag(2 3)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store rdyr3

xtabond2 ROE L.ROE dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7, gmm(ROE, lag(2 3)) gmm(KZIndex, lag(2 3)) ///
gmm(df_KZ, lag(2 4)) gmm(RD_intensity, lag(2 5)) gmm(Size, lag(2 5)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7) twostep robust
est store rdyr4

esttab rdyr1 rdyr2 rdyr3 rdyr4, order(L.ROA L.ROE dfindexcity KZIndex df_KZ Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity) compress nogap ///
star(* 0.10 ** 0.05 *** 0.01) mtitles("ROA" "ROA" "ROE" "ROE" "ROS" "ROS") se b(%9.3f) se(%9.3f) noconstant
```
\
 ![](https://fig-lianxh.oss-cn-shenzhen.aliyuncs.com/%E4%BD%9C%E8%80%85%E4%B9%94%E5%88%9A_%E6%95%B0%E5%AD%97%E9%87%91%E8%9E%8D%E4%B8%8E%E8%9E%8D%E8%B5%84%E7%BA%A6%E6%9D%9F%E5%AF%B9%E8%B4%A2%E5%8A%A1%E7%BB%A9%E6%95%88_Fig2.png) 

动态面板模型结果见表 5。Hansen 检验和 AR 测试证实了动态模型的规定是恰当的。滞后一期因变量的系数显著，反映了企业财务绩效的动态特征。
数字金融的效果是积极和显著的。与先前的研究一致，财务约束对财务绩效起着负面作用，且交互项的系数为负显著。
创新是影响企业财务绩效的重要因素。在上述分析中，没有控制企业研发支出，因为创新可能是从数字金融和融资约束到财务绩效的路径中的一个干预变量，
不应该受到控制。然而，我们增加了研发强度（以研发支出与总资产的比率衡量）来检查稳健性。结果见表 5 第（5）-（8）列。Hansen 检验和 AR 检验仍然证实了估计的有效性。这些假设再次得到支持。

### 2.3 稳健性检验

```
*Dynamic model for FCIndex（Robustness Check）
*no RD
xtabond2 ROA L.ROA dfindexcity FC Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 3)) gmm(FC, lag(2 5)) ///
gmm(Size, lag(2 3)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC1

xtabond2 ROA L.ROA dfindexcity FC df_FC Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 3)) gmm(FC, lag(2 4)) ///
gmm(Size, lag(2 4)) gmm(df_FC, lag(2 4)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC2

xtabond2 ROE L.ROE dfindexcity FC Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 6)) gmm(FC, lag(2 6)) ///
gmm(Size, lag(2 6)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC3

xtabond2 ROE L.ROE dfindexcity FC df_FC Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 3)) gmm(FC, lag(2 5)) ///
gmm(Size, lag(2 4)) gmm(df_FC, lag(2 6)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC4

esttab FC1 FC2 FC3 FC4, order(L.ROA L.ROE dfindexcity FC df_FC Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity) compress ///
nogap star(* 0.10 ** 0.05 *** 0.01) mtitles("ROA" "ROA" "ROE" "ROE" "ROS" "ROS") se b(%9.3f) se(%9.3f) noconstant

*RD controlled
xtabond2 ROA L.ROA dfindexcity FC Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7, gmm(ROA, lag(2 3)) gmm(FC, lag(2 5)) ///
gmm(Size, lag(2 3)) gmm(RD_intensity, lag(2 3)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC5

xtabond2 ROA L.ROA dfindexcity FC df_FC Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7, gmm(ROA, lag(2 3)) gmm(FC, lag(2 4)) ///
gmm(Size, lag(2 4)) gmm(df_FC, lag(2 4)) gmm(RD_intensity, lag(2 3)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC6

xtabond2 ROE L.ROE dfindexcity FC Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7, gmm(ROE, lag(2 6)) gmm(FC, lag(2 6)) ///
gmm(Size, lag(2 6)) gmm(RD_intensity, lag(2 3)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC7

xtabond2 ROE L.ROE dfindexcity FC df_FC Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity y2-y7, gmm(ROE, lag(2 3)) gmm(FC, lag(2 5)) ///
gmm(Size, lag(2 4)) gmm(df_FC, lag(2 6)) gmm(RD_intensity, lag(2 3)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store FC8

esttab FC5 FC6 FC7 FC8, order(L.ROA L.ROE dfindexcity FC df_FC Size Age SOE Topshare Boardsize CEOduality Findev RD_intensity) compress nogap ///
star(* 0.10 ** 0.05 *** 0.01) mtitles("ROA" "ROA" "ROE" "ROE" "ROS" "ROS") se b(%9.3f) se(%9.3f) noconstant
```
\
 ![](https://fig-lianxh.oss-cn-shenzhen.aliyuncs.com/%E4%BD%9C%E8%80%85%E4%B9%94%E5%88%9A_%E6%95%B0%E5%AD%97%E9%87%91%E8%9E%8D%E4%B8%8E%E8%9E%8D%E8%B5%84%E7%BA%A6%E6%9D%9F%E5%AF%B9%E8%B4%A2%E5%8A%A1%E7%BB%A9%E6%95%88_Fig3.png) 

KZ 指数因其与托宾 Q 可能的错误测量相关而受到批评。针对这一问题，FC 指数被用作稳健性的替代变量。数字金融的系数在所有情况下都是正显著的。
无论 RD 强度是否得到控制，融资约束系数对 ROA 都是负显著的，且交互项的系数是负显著的。我们的结论是稳健的。

### 2.4 异质性分析

```
*Heterogeneity analysis
egen medsize = median(Size)
gen sizeGroup = Size > medsize
gen east = region == "东部"

*frim scale
gen size_dfindex = sizeGroup * dfindexcity
gen size_KZIndex = sizeGroup * KZIndex
*ROA
*dfindex_city
xtabond2 ROA L.ROA dfindexcity KZIndex size_dfindex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 3)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 6)) gmm(size_dfindex, lag(2 6)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store size1
*KZIndex
xtabond2 ROA L.ROA dfindexcity KZIndex size_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 4)) gmm(size_KZIndex, lag(2 3)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store size2

*ROE
*dfindex_city
xtabond2 ROE L.ROE dfindexcity KZIndex size_dfindex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 3)) ///
gmm(KZIndex, lag(2 5)) gmm(Size, lag(2 6)) gmm(size_dfindex, lag(2 6)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store size3
*KZIndex
xtabond2 ROE L.ROE dfindexcity KZIndex size_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 3)) ///
gmm(KZIndex, lag(2 5)) gmm(Size, lag(2 4)) gmm(size_KZIndex, lag(2 2)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store size4

esttab size1 size2 size3 size4, order(L.ROA L.ROE dfindexcity KZIndex size_dfindex size_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev) compress nogap ///
star(* 0.10 ** 0.05 *** 0.01) se b(%9.3f) se(%9.3f) noconstant
```
\
 ![](https://fig-lianxh.oss-cn-shenzhen.aliyuncs.com/%E4%BD%9C%E8%80%85%E4%B9%94%E5%88%9A_%E6%95%B0%E5%AD%97%E9%87%91%E8%9E%8D%E4%B8%8E%E8%9E%8D%E8%B5%84%E7%BA%A6%E6%9D%9F%E5%AF%B9%E8%B4%A2%E5%8A%A1%E7%BB%A9%E6%95%88_Fig4.png) 

企业规模异质性结果表明，数字金融的边际效应对大公司较小（对小公司较大）。这与小公司更容易受到金融障碍的影响是一致的，
数字金融为它们提供了新的融资机会。融资约束的负面影响在小公司中较小（在大公司中较大）。

```
*frim ownership
gen soe_dfindex = SOE * dfindexcity
gen soe_KZIndex = SOE * KZIndex
*ROA
*dfindex_city
xtabond2 ROA L.ROA dfindexcity KZIndex soe_dfindex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 4)) iv(dfindexcity Age SOE soe_dfindex Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store soe1

*KZIndex
xtabond2 ROA L.ROA dfindexcity KZIndex soe_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROA, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 4)) gmm(soe_KZIndex, lag(2 6)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store soe2

*ROE
*dfindex_city
xtabond2 ROE L.ROE dfindexcity KZIndex soe_dfindex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 4)) ///
gmm(KZIndex, lag(2 5)) gmm(Size, lag(2 6)) iv(dfindexcity Age SOE soe_dfindex Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store soe3

*KZIndex
xtabond2 ROE L.ROE dfindexcity KZIndex soe_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7, gmm(ROE, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 3)) gmm(soe_KZIndex, lag(2 4)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7) twostep robust
est store soe4

esttab soe1 soe3 soe2 soe4, order(L.ROA L.ROE dfindexcity KZIndex soe_dfindex soe_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev) ///
compress nogap star(* 0.10 ** 0.05 *** 0.01) se b(%9.3f) se(%9.3f) noconstant
```
\
 ![](https://fig-lianxh.oss-cn-shenzhen.aliyuncs.com/%E4%BD%9C%E8%80%85%E4%B9%94%E5%88%9A_%E6%95%B0%E5%AD%97%E9%87%91%E8%9E%8D%E4%B8%8E%E8%9E%8D%E8%B5%84%E7%BA%A6%E6%9D%9F%E5%AF%B9%E8%B4%A2%E5%8A%A1%E7%BB%A9%E6%95%88_Fig5.png) 

关于企业所有权，交互项 SOEDF 在 10% 的水平上是负显著的，这表明数字金融的影响在国有企业中规模较小。一方面，国有企业可以获得更多的政府支持，拥有更多的外部融资机会，数字金融的边际效应较小；另一方面，国有企业面临着追求政治和社会目标的压力，面临着更严重的代理问题，导致投资效率低下，抑制了数字金融的作用。

```
*firm region
gen east_dfindex = east * dfindexcity
gen east_KZIndex = east * KZIndex
*ROA
*dfindex_city
xtabond2 ROA L.ROA dfindexcity KZIndex east_dfindex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7 east, gmm(ROA, lag(2 3)) ///
gmm(KZIndex, lag(2 5)) gmm(Size, lag(2 5)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7  east_dfindex east) twostep robust
est store east1

*KZIndex
xtabond2 ROA L.ROA dfindexcity KZIndex east_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7 east, gmm(ROA, lag(2 5) collapse) ///
gmm(KZIndex, lag(2 4) collapse) gmm(Size, lag(2 4) collapse) gmm(east_KZIndex, lag(2 4) collapse) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7 east) twostep robust
est store east2

*ROE
*dfindex_city
xtabond2 ROE L.ROE dfindexcity KZIndex east_dfindex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7 east, gmm(ROE, lag(2 4)) ///
gmm(KZIndex, lag(2 4)) gmm(Size, lag(2 4)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7 east_dfindex east) twostep robust
est store east3

*KZIndex
xtabond2 ROE L.ROE dfindexcity KZIndex east_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev y2-y7 east, gmm(ROE, lag(2 3)) ///
gmm(KZIndex, lag(2 3)) gmm(Size, lag(2 4)) gmm(east_KZIndex, lag(2 4)) iv(dfindexcity Age SOE Topshare Boardsize CEOduality Findev y2-y7 east) twostep robust
est store east4


esttab east1 east3 east2 east4, order(L.ROA L.ROE dfindexcity KZIndex east_dfindex east_KZIndex Size Age SOE Topshare Boardsize CEOduality Findev) ///
compress nogap star(* 0.10 ** 0.05 *** 0.01) mtitles("ROA" "ROA" "ROE" "ROE") se b(%9.3f) se(%9.3f) noconstant
```
\
 ![](https://fig-lianxh.oss-cn-shenzhen.aliyuncs.com/%E4%BD%9C%E8%80%85%E4%B9%94%E5%88%9A_%E6%95%B0%E5%AD%97%E9%87%91%E8%9E%8D%E4%B8%8E%E8%9E%8D%E8%B5%84%E7%BA%A6%E6%9D%9F%E5%AF%B9%E8%B4%A2%E5%8A%A1%E7%BB%A9%E6%95%88_Fig6.png) 

尽管先前的研究表明，数字金融的影响在欠发达地区更为突出，但研究结果并未显示出数字金融作用的显著地区差异。在我们的研究中，有两个可能的原因可以解释这一点：一方面，东部地区经济更加发达，位于该地区的企业不仅有更多的融资机会，而且面临更激烈的竞争。这种竞争反过来又增加了数字金融的边际效应。
另一方面，在中西部地区，新能源资源丰富，但基础设施不足；在东部地区，对新能源的需求很高，但供应没有得到充分保障。这进一步抑制了数字金融在中西部地区的作用，增加了东部地区的竞争强度。

## 3. 相关推文

>  **Note：** 产生如下推文列表的 Stata 命令为： <br> 
       <font color='red'>lianxh 论文, m</font>  <br> 
安装最新版 <font color='red'>lianxhm</font> 命令： <br> 
        <font color='red'>ssc install lianxh, replace</font>