plugins {
    id 'java'
    id 'org.springframework.boot' version "${springBootVersion}"
    id 'io.spring.dependency-management' version '1.1.4'
    id 'com.bmuschko.docker-spring-boot-application' version '9.4.0'
}

description 'silky 根模块'

// 为所有项目进行配置，包括根项目
allprojects {
    sourceCompatibility = '21'

    group = "${groupId}"
    version = '1.0.1'

    apply plugin: 'java'
    apply plugin: 'maven-publish'
    apply plugin: 'io.spring.dependency-management'

    // 为所有项目设置编译、测试、文档生成编码方式为UTF-8
    task setEncoding {
        [compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'
        doLast {
            task -> println "项目名： $task.project.name " + "说明： $task.project.description "
        }
    }
    repositories {
        maven { url "https://maven.aliyun.com/nexus/content/groups/public/" }
        mavenCentral()
    }
}

// 基础工具jar单独配置插件，发布方式
project(':core') {
    apply plugin: 'java-library'
    // 发布配置
    publishing {
        publications {
            mavenPublish(MavenPublication) {
                from components.java
            }
        }
        repositories {
            maven {
                allowInsecureProtocol = true
                url "${privateRepositoriesUrl}"
                credentials {
                    username "${mavenuser}"
                    password "${mavenpassword}"
                }
            }
        }
        // 发布包含JavadocJar与SourceJar
        java {
            withJavadocJar()
            withSourcesJar()
        }
    }
}

// 为所有子项目进行配置，该配置优先级比 allprojects 高
subprojects {
    println "项目名称：" + project.name
    if (project.name != 'core') {
        apply plugin: 'org.springframework.boot'
        // 发布配置
        publishing {
            // 发布方式
            publications {
                bootJava(MavenPublication) {
                    artifact bootJar
                }
            }
            // 发布仓库
            repositories {
                maven {
                    allowInsecureProtocol = true
                    url "${privateRepositoriesUrl}"
                    credentials {
                        username "${mavenuser}"
                        password "${mavenpassword}"
                    }
                }
            }
            // 发布包含JavadocJar与SourceJar
            java {
                withJavadocJar()
                withSourcesJar()
            }
        }
    }
    // maven仓库配置
    repositories {
        maven { url "${aliyunRepositoriesUrl}" }
        maven {
            allowInsecureProtocol = true
            url "${privateRepositoriesUrl}"
            credentials {
                username "${mavenuser}"
                password "${mavenpassword}"
            }
        }
        mavenCentral()
    }
    // 依赖管理
    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
        }
        imports {
            mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
        }
    }
    // 测试
    test {
        useJUnitPlatform()
    }
    java {
        withJavadocJar()
        withSourcesJar()
    }
}

// 根模块发布配置
publishing {
    // 发布方式
    publications {
        mavenJava(MavenPublication) {
            pom {
                name = project.name
                description = '旨在丝滑开发'
                url = 'http://www.sztaiji.com/'
                properties = [testKey: "testValue"]
                developers {
                    developer {
                        id = 'TJ2580'
                        name = 'List Jiang'
                        email = 'jiangdewen@linewell.com'
                    }
                }
            }
        }
    }
    // 发布仓库
    repositories {
        maven {
            allowInsecureProtocol = true
            url "${privateRepositoriesUrl}"
            credentials {
                username "${mavenuser}"
                password "${mavenpassword}"
            }
        }
    }
}

bootJar {
    enabled false
}
jar {
    enabled false
}